win7创建虚拟wifi，手机连接成功，但就是上不了网！要怎么解决

打开记事本 把这粘贴上 保存为bat格式文件，然后运行，他会教你怎么设置

@echo off
color 3f
mode con: cols=60 lines=20
ver | find "6.1">nul
if %errorlevel% == 0 (goto :mainmenu) else (goto :note)

:note
echo 您的系统不是Win7系统，可能无法使用WiFi热点工具！
echo 若您的系统是Win7、Win8或Vista请选择继续，否则建议您退出。
echo.
set /p c=是否继续？[Y-继续 N-退出]：
if "%c%" == "Y" (goto :mainmenu) else (
if "%c%" == "y" (goto :mainmenu) else (goto :quit))

:mainmenu
cls
echo ┌—————————————————————————┐
echo │ WiFi热点创建工具Ver2.0[支持Win7、Win8、Vista] │
echo │ │
echo │1、创建虚拟WiFi网卡（创建时需设置账号、密码） │
echo │2、删除虚拟WiFi网卡 │
echo │ │
echo │3、开启WiFi热点 （创建好虚拟WiFi网卡后再开启） │
echo │4、关闭WiFi热点 │
echo │ │
echo │5、使用教程 （开启完成后可参考这个） │
echo │6、查看WiFi信息 （可以查看连接到自己WiFi的用户）│
echo │ │
echo │7、修改WiFi密码 （建议先关闭热点，再修改密码） │
echo │8、退出程序 │
echo └—————————————————————————┘
set /p select=请选择:
if "%select%" == "1" (goto :create) else (
if "%select%" == "2" (goto :delete) else (
if "%select%" == "3" (goto :open) else (
if "%select%" == "4" (goto :close) else (
if "%select%" == "5" (goto :introduce) else (
if "%select%" == "6" (goto :information) else (
if "%select%" == "7" (goto :password) else (
if "%select%" == "8" (goto :quit) else (goto :error))))))))

:create
cls
sc config BFE start= demand>nul 2>nul
net start BFE>nul 2>nul
sc config mpsdrv start= demand>nul 2>nul
net start mpsdrv>nul 2>nul
sc config MpsSvc start= auto>nul 2>nul
net start MpsSvc>nul 2>nul
echo [创建虚拟WiFi网卡]
set /p username=请输入您要设置的WiFi账号：
set /p password=请输入您要设置的WiFi密码（至少8位）：
netsh wlan set hostednetwork mode=allow ssid=%username% key=%password% keyusage=persistent>nul
if %errorlevel% == 0 (echo 命令执行成功...&&echo.&&echo 您的WIFI账号为：[%username%] 密码为：[%password%]) else (echo 命令执行失败，密码位数少于8位或其他原因...)
echo.
set /p select1=是否返回主界面？[Y-返回 N-退出]：
if "%select1%" == "Y" (goto :mainmenu) else (
if "%select1%" == "y" (goto :mainmenu) else (goto :quit))

:delete
cls
echo [删除虚拟WiFi网卡]
echo 提示：若是你没有创建过虚拟WiFi网卡，删除将是无效的。
netsh wlan stop hostednetwork>nul
netsh wlan set hostednetwork mode=disallow>nul
if %errorlevel% == 0 (echo 命令执行成功...) else (echo 命令执行失败，是否未曾创建过虚拟WiFi网卡？)
echo.
set /p select1=是否返回主界面？[Y-返回 N-退出]：
if "%select1%" == "Y" (goto :mainmenu) else (
if "%select1%" == "y" (goto :mainmenu) else (goto :quit))

:open
cls
echo [开启WiFi热点]
echo 提示：若您没有创建过虚拟WiFi网卡，开启WiFi热点也将是无效的！
netsh wlan start hostednetwork>nul
if %errorlevel% == 0 (echo 命令执行成功...) else (echo 命令执行失败，您是否还未创建过虚拟WiFi网卡？&&echo.&&echo 【若创建过，还出现此问题，请按如下方法操作：】&&echo.&&echo 检查您的WiFi功能是否开启，一般通过Fn+F2快捷键开启。[即按键上有无线标志的那个，有的为Fn+F4或F12。])
if %errorlevel% == 0 start control ncpa.cpl>nul
echo.
set /p select1=是否返回主界面？[Y-返回 N-退出]：
if "%select1%" == "Y" (goto :mainmenu) else (
if "%select1%" == "y" (goto :mainmenu) else (goto :quit))

:close
cls
echo [关闭WiFi热点]
echo 提示：若您没开启过WiFi热点，关闭也是无效的。
netsh wlan stop hostednetwork>nul
if %errorlevel% == 0 (echo 命令执行成功...) else (echo 命令执行失败，WiFi热点没有开启过或者其它原因。)
echo.
set /p select1=是否返回主界面？[Y-返回 N-退出]：
if "%select1%" == "Y" (goto :mainmenu) else (
if "%select1%" == "y" (goto :mainmenu) else (goto :quit))

:information
cls
echo [WiFi热点信息]
netsh wlan show hostednetwork
echo.
set /p select1=是否返回主界面？[Y-返回 N-退出]：
if "%select1%" == "Y" (goto :mainmenu) else (
if "%select1%" == "y" (goto :mainmenu) else (goto :quit))

:introduce
cls
echo ┌—————————————————————————┐
echo │ WiFi热点创建工具Ver2.0[使用方法] │
echo │ │
echo │A、若第一次使用，就选1输入账号密码，然后选3开启。 │
echo │B、成功后会自动打开【适配器设置】页面，然后如下： │
echo │ │
echo │C、【若您是使用宽带连接拨号上网，请如下操作】： │
echo │D、[宽带连接]--属性--共享--勾选允许其他网络用户...│
echo │E、下面选择“无线网络连接2”，参考“宽带拨号.png”│
echo │ │
echo │F、【若是您使用的校园网或其它，请如下操作】： │
echo │G、[本地连接]--属性--共享--勾选允许其他网络用户...│
echo │H、下面选择“无线网络连接2”，参考“校园网.png” │
echo │ │
echo └—————————————————————————┘
set /p select1=是否返回主界面？[Y-返回 N-退出]：
if "%select1%" == "Y" (goto :mainmenu) else (
if "%select1%" == "y" (goto :mainmenu) else (goto :quit))

:password
cls
echo [WiFi密码修改]
echo 【注：建议的话，先选关闭WiFi热点，修改完成后，再开启即可！】
set /p pwd=请输入您要设置的新密码[不少于8位]：
netsh wlan set hostednetwork key=%pwd% >nul
if %errorlevel% == 0 (echo 恭喜您，密码修改成功...) else (echo 密码修改失败，密码位数少于8位或其他原因！)
echo.
set /p select1=是否返回主界面？[Y-返回 N-退出]：
if "%select1%" == "Y" (goto :mainmenu) else (
if "%select1%" == "y" (goto :mainmenu) else (goto :quit))

:error
echo 您的选择不存在或者输入有误，请重新选择!
pause>nul 2>nul;
goto :mainmenu

:quit
echo 感谢您的使用，按任意键退出程序...
pause>nul 2>nul;
exit

下载一个免费WiFi就可以啦，搞的那么复杂干什么。

手机使用静态地址就行。